home *** CD-ROM | disk | FTP | other *** search
/ Light ROM 1 / LIGHT-ROM 1 (Amiga Library Services)(1994).iso / ffdisks / d967.lha / MUI_usr / mui20usr.lha / MUI / MUI-Install < prev    next >
Text File  |  1994-02-10  |  8KB  |  326 lines
  1. (transcript "Installing Magic User Interface System...")
  2.  
  3.  
  4. ; **************************************************************************
  5. ; **************************************************************************
  6. ; **************************************************************************
  7.  
  8.  
  9. (set @default-dest "SYS:")
  10.  
  11.  
  12. ; **************************************************************************
  13. ; **************************************************************************
  14. ; **************************************************************************
  15.  
  16.  
  17. (copylib
  18.     (help @copylib-help)
  19.     (prompt "Installing muimaster.library...")
  20.     (confirm)
  21.     (source "Libs/muimaster.library")
  22.     (dest
  23.         (askdir
  24.             (prompt "Please select a place for \"muimaster.library\".")
  25.             (help @askdir-help)
  26.             (default "LIBS:")
  27.         )
  28.     )
  29. )
  30.  
  31.  
  32. (complete 10)
  33.  
  34.  
  35. ; **************************************************************************
  36. ; **************************************************************************
  37. ; **************************************************************************
  38.  
  39.  
  40. (set classdest
  41.     (askdir
  42.         (prompt "Please select a place for the classes. A sub drawer called \"MUI\" will be created here.")
  43.         (help @askdir-help)
  44.         (default "SYS:Classes")
  45.         (newpath)
  46.     )
  47. )
  48.  
  49.  
  50. (makedir classdest)
  51.  
  52. (makedir (tackon classdest "MUI"))
  53.  
  54. (if (exists (tackon classdest "MUI/application.mui"))
  55. (
  56.     (if (askbool (help @askbool-help) (prompt "Some old classes are obsolete and should be deleted. Do you want to delete them now?"))
  57.     (
  58.         (foreach (tackon classdest "MUI") "#?.mui"
  59.             (delete
  60.                 (tackon (tackon classdest "MUI") @each-name)
  61.                 (prompt "Deleting obsolete classes...")
  62.             )
  63.         )
  64.     )
  65.     )
  66. )
  67. )
  68.  
  69.  
  70. (foreach "Classes/MUI" "#?.mui"
  71.     (copylib
  72.         (prompt "Installing Classes...")
  73.         (source (tackon "Classes/MUI" @each-name))
  74.         (help @copylib-help)
  75.         (dest (tackon classdest "MUI"))
  76.     )
  77. )
  78.  
  79.  
  80. (complete 20)
  81.  
  82.  
  83. ; **************************************************************************
  84. ; **************************************************************************
  85. ; **************************************************************************
  86.  
  87.  
  88. (copylib
  89.     (prompt "Installing the preferences program...")
  90.     (source "Prefs/MUI")
  91.     (confirm)
  92.     (infos)
  93.     (noposition)
  94.     (help @copylib-help)
  95.     (dest
  96.         (askdir
  97.             (prompt "Please select a place for the preferences program.")
  98.             (help @askdir-help)
  99.             (default "SYS:Prefs")
  100.             (newpath)
  101.         )
  102.     )
  103. )
  104.  
  105.  
  106. (complete 30)
  107.  
  108.  
  109. ; **************************************************************************
  110. ; **************************************************************************
  111. ; **************************************************************************
  112.  
  113. (if (exists "envarc:mui/-global.prefs")
  114. (
  115.     (if (askbool (help @askbool-help) (prompt "Your old preferences are obsolete and should be deleted. This will not affect window positions and application's private prefs. Do you want to delete the old config files now (recommended)?"))
  116.     (
  117.         (foreach "envarc:mui" "#?.prefs"
  118.             (delete
  119.                 (tackon "envarc:mui" @each-name)
  120.                 (prompt "Deleting obsolete preferences files...")
  121.             )
  122.         )
  123.     )
  124.     )
  125. )
  126. )
  127.  
  128. (complete 40)
  129.  
  130.  
  131. ; **************************************************************************
  132. ; **************************************************************************
  133. ; **************************************************************************
  134.  
  135.  
  136. (if (askbool (help @askbool-help) (prompt "Do you want to install the german language catalog for the preferences program?"))
  137. (
  138.     (copyfiles
  139.         (prompt "Installing the german language catalog...")
  140.         (source "Locale/Catalogs/Deutsch/MUI-Prefs.catalog")
  141.         (help @copyfiles-help)
  142.         (dest "locale:Catalogs/Deutsch/")
  143.     )
  144. )
  145. )
  146.  
  147. (complete 50)
  148.  
  149.  
  150. ; **************************************************************************
  151. ; **************************************************************************
  152. ; **************************************************************************
  153.  
  154.  
  155. (if (askbool (help @askbool-help) (prompt "Do you want to install the default AppIcon for MUI Programs?"))
  156. (
  157.     (copyfiles
  158.         (prompt "Installing the AppIcon...")
  159.         (source "Prefs/Env-Archive/Sys/def_MUI.info")
  160.         (help @copyfiles-help)
  161.         (dest "envarc:Sys/")
  162.     )
  163. )
  164. )
  165.  
  166.  
  167. (complete 60)
  168.  
  169.  
  170. ; **************************************************************************
  171. ; **************************************************************************
  172. ; **************************************************************************
  173.  
  174.  
  175. (if (askbool (help @askbool-help) (prompt "Do you want to install the additional BOOPSI images?"))
  176. (
  177.     (set boopsidest
  178.         (askdir
  179.             (prompt "Please select a place for the BOOPSI images.")
  180.             (help @askdir-help)
  181.             (default (tackon classdest "Images"))
  182.             (newpath)
  183.         )
  184.     )
  185.  
  186.     (foreach "Classes/Images" "#?.image"
  187.         (copylib
  188.             (prompt "Installing BOOPSI Images...")
  189.             (source (tackon "Classes/Images" @each-name))
  190.             (help @copylib-help)
  191.             (dest boopsidest)
  192.         )
  193.     )
  194. )
  195. )
  196.  
  197.  
  198. (complete 70)
  199.  
  200.  
  201. ; **************************************************************************
  202. ; **************************************************************************
  203. ; **************************************************************************
  204.  
  205.  
  206. (if (askbool (help @askbool-help) (prompt "Installing the additional MUI brushes is recommended if you want to use the preferences builtin presets. If you change the path, you will ran into problems. Do you want to install them now?"))
  207. (
  208.     (copyfiles
  209.         (prompt "Installing MUI brushes...")
  210.         (help @copyfiles-help)
  211.         (source "Prefs/MUI-Images")
  212.         (all)
  213.         (dest
  214.             (askdir
  215.                 (prompt "Please select a place for the brushes.")
  216.                 (help @askdir-help)
  217.                 (default "sys:prefs/MUI-Images")
  218.                 (newpath)
  219.             )
  220.         )
  221.     )
  222. )
  223. )
  224.  
  225.  
  226. (complete 80)
  227.  
  228.  
  229. ; **************************************************************************
  230. ; **************************************************************************
  231. ; **************************************************************************
  232.  
  233.  
  234. (if (askbool (help @askbool-help) (prompt "Do you want to install the english online help manual for the preferences program?"))
  235. (
  236.     (if (exists "libs:amigaguide.library")
  237.     (
  238.         (copyfiles
  239.             (prompt "Installing the english online help...")
  240.             (source "Docs/English/MUI.guide")
  241.             (help @copyfiles-help)
  242.             (dest
  243.                 (set manpath (askdir
  244.                     (prompt "Please select a place for the english online help.")
  245.                     (help @askdir-help)
  246.                     (default "HELP:english")
  247.                     (newpath)
  248.                 ))
  249.             )
  250.         )
  251.     )
  252.    (
  253.         (message "I couldn't locate \"amigaguide.libary\" on your system, you won't be able to use online help.")
  254.     )
  255.     )
  256. )
  257. )
  258.  
  259.  
  260. (complete 90)
  261.  
  262.  
  263. ; **************************************************************************
  264. ; **************************************************************************
  265. ; **************************************************************************
  266.  
  267.  
  268. (if (askbool (help @askbool-help) (prompt "Do you want to install the german online help manual for the preferences program?"))
  269. (
  270.     (if (exists "libs:amigaguide.library")
  271.     (
  272.         (copyfiles
  273.             (prompt "Installing the german online help...")
  274.             (source "Docs/Deutsch/MUI.guide")
  275.             (help @copyfiles-help)
  276.             (dest
  277.                 (askdir
  278.                     (prompt "Please select a place for the german online help.")
  279.                     (help @askdir-help)
  280.                     (default "HELP:deutsch")
  281.                     (newpath)
  282.                 )
  283.             )
  284.         )
  285.     )
  286.    (
  287.         (message "I couldn't locate \"amigaguide.libary\" on your system, you won't be able to use online help.")
  288.     )
  289.     )
  290. )
  291. )
  292.  
  293.  
  294. (complete 95)
  295.  
  296.  
  297.  
  298. ; **************************************************************************
  299. ; **************************************************************************
  300. ; **************************************************************************
  301.  
  302.  
  303. (set vernum (getversion "exec.library" (resident)))
  304. (set ver (/ vernum 65536))
  305.  
  306. (if (< ver 39)
  307. (
  308.     (startup "MUI"
  309.         (prompt "You are not running Kickstart 3.0 or higher, so I have to add some commands to your user-startup.")
  310.         (help @startup-help)
  311.         (command "assign add LIBS: \"" classdest "\"")
  312.     )
  313. )
  314. )
  315.  
  316.  
  317. (complete 100)
  318.  
  319.  
  320. ; **************************************************************************
  321. ; **************************************************************************
  322. ; **************************************************************************
  323.  
  324.  
  325. (exit "Please reboot now!")
  326.